Objeto AddIn

Application AddIns (AddIn)

Representa um único suplemento, instalado ou não. O objeto AddIn é um membro da coleção AddIns. A coleção AddIns contém uma lista de todos os suplementos disponíveis do Microsoft Excel, independente de estarem instalados. Essa lista corresponde à lista de suplementos exibidos na caixa de diálogo Suplementos (menu Ferramentas).

Usando o objeto Addin

Use AddIns(index), onde index é o número de índice ou título do suplemento, para retornar um único objeto AddIn. O exemplo seguinte instala o suplemento Analysis Toolpak.

AddIns("analysis toolpak").Installed = True

Não confunda o título do suplemento, que aparece na caixa de diálogo Suplementos, com o nome do suplemento, que é o nome do arquivo do suplemento. Você precisa escrever o título do suplemento exatamente como ele é escrito na caixa de diálogo Suplementos, mas não é necessário haver correspondência de maiúsculas e minúsculas.

O número do índice representa a posição do suplemento na caixa Suplementos disponíveis da caixa de diálogo Suplementos. O exemplo seguinte cria uma lista que contém propriedades especificadas dos suplementos disponíveis.

With Worksheets("sheet1")
    .Rows(1).Font.Bold = True
    .Range("a1:d1").Value = _
        Array("Name", "Full Name", "Title", "Installed")
    For i = 1 To AddIns.Count
        .Cells(i + 1, 1) = AddIns(i).Name
        .Cells(i + 1, 2) = AddIns(i).FullName
        .Cells(i + 1, 3) = AddIns(i).Title
        .Cells(i + 1, 4) = AddIns(i).Installed
    Next
    .Range("a1").CurrentRegion.Columns.AutoFit
End With

Comentários

O método Add adiciona um suplemento à lista de suplementos disponíveis, mas não instala o suplemento. Defina a propriedade Installed do suplemento como True para instalar o suplemento. Para instalar um suplemento que não apareça na lista de suplementos disponíveis, você precisa primeiro usar o método Add e definir a propriedade Installed. Isto pode ser feito em uma única etapa, como mostrado no exemplo seguinte (observe que você usa o nome do suplemento, e não o seu título, com o método Add).

AddIns.Add("generic.xll").Installed = True

Use Workbooks(index) onde index é o nome do arquivo do suplemento (não seu título) para retornar uma referência à pasta de trabalho correspondente para um suplemento carregado. Você precisa usar o nome de arquivo porque suplementos carregados normalmente não aparecem na coleção Workbooks. Este exemplo define a variável pdt com a pasta de trabalho de Myaddin.xla.

Set wb = Workbooks("myaddin.xla")

O exemplo seguinte define a variável pdt com a pasta de trabalho do suplemento Analysis Toolpak.

Set wb = Workbooks(AddIns("analysis toolpak").Name)

Se a propriedade Installed retornar True e as chamadas a funções no suplemento continuarem a falhar, o suplemento poderá não ser realmente carregado. Isto ocorre porque o objeto Addin indica se o suplemento está instalado e se ele existe, mas não representa o conteúdo real da pasta de trabalho do suplemento. Para garantir que um suplemento instalado seja carregado, você deve abrir a pasta de trabalho desse suplemento. O exemplo seguinte abre a pasta de trabalho do suplemento chamado "My Addin" se o suplemento não estiver já presente na coleção Workbooks.

On Error Resume Next    ' turn off error checking
Set wbMyAddin = Workbooks(Addins("My Addin").Name)
lastError = Err
On Error Goto 0        ' restore error checking
If lastError <> 0 Then
    ' the add-in workbook isn't currently open. Manually open it.
    Set wbMyAddin = Workbooks.Open(Addins("My Addin").FullName)
End If