Coleção CustomProperties

Vários objetos
CustomProperties
CustomProperty

Uma coleção de objetos CustomProperty que representa informações adicionais. As informações podem ser usadas como metadados do XML.

Usar a coleção CustomProperties

Use a propriedade Properties do objeto SmartTag ou a propriedade CustomProperties do objeto Worksheet para retornar uma coleção CustomProperties.

Depois que uma coleção CustomProperties foi retornada, você pode adicionar metadados a planilhas e marcas inteligentes de acordo com a escolhida para trabalhar.

Para adicionar metadados a uma planilha, use a propriedade CustomProperties com o método Add.

O exemplo a seguir demonstra esse recurso. Nesse exemplo, o Microsoft Excel adiciona informações de identificador à planilha ativa e retorna o nome e valor ao usuário. 

Sub CheckCustomProperties()

    Dim wksSheet1 As Worksheet

    Set wksSheet1 = Application.ActiveSheet

    ' Add metadata to worksheet.
    wksSheet1.CustomProperties.Add _
        Name:="Market", Value:="Nasdaq"

    ' Display metadata.
    With wksSheet1.CustomProperties.Item(1)
        MsgBox .Name & vbTab & .Value
    End With

End Sub

Para adicionar metadados a uma marca inteligente, use a propriedade Properties com o método Add.

O exemplo a seguir demonstra esse recurso. Nesse exemplo, o Microsoft Excel adiciona uma marca inteligente chamada "MSFT" à célula A1, em seguida adiciona metadados extras chamados "Market" com o valor de "Nasdaq" à marca inteligente e depois retorna o valor da propriedade ao usuário. Esse exemplo supõe que o sistema host esteja conectado à Internet ao executar esse exemplo de código e que o identificador verificado "Stock Ticker Symbol Recognizer" esteja ativado no Microsoft Excel. 

Sub UseProperties()

    Dim strLink As String
    Dim strType As String

    ' Define smart tag variables.
    strLink = "urn:schemas-microsoft-com:smarttags#stocktickerSymbol"
    strType = "stockview"

    Range("A1").Formula = "MSFT"

    ' Add a property for MSFT smart tag and define its value.
    Range("A1").SmartTags.Add(strLink).Properties.Add _
        Name:="Market", Value:="Nasdaq"

    ' Notify the user of the smart tag's value.
    MsgBox Range("A1").SmartTags.Add(strLink).Properties("Market").Value

End Sub